AC_PREREQ([2.71])
AC_INIT([engine], [alpha])
AC_CONFIG_SRCDIR([src/engine.cpp])
AC_CONFIG_HEADERS([src/config.h])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([foreign subdir-objects])
AC_CONFIG_FILES([Makefile src/Makefile src/spvshaders/Makefile])
AC_REQUIRE_AUX_FILE([tap-driver.sh])

CXXFLAGS_save="$CXXFLAGS"
LIBS_save="$LIBS"
CXXFLAGS=
LIBS=

AC_PROG_CXX
AC_PROG_AWK
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_MKDIR_P

AC_CHECK_HEADERS([stdint.h])

AC_CHECK_HEADER_STDBOOL
AC_TYPE_INT16_T
AC_TYPE_INT32_T
AC_TYPE_SIZE_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T

AC_CHECK_FUNCS([floor memset modf pow setlocale sqrt strtol])

AC_ARG_ENABLE([debug],
  [AS_HELP_STRING([--enable-debug],
    [make every path of files not built relative to the source tree, unset NDEBUG])],
  [enable_debug=$enableval],
  [enable_debug=no])
AM_CONDITIONAL([DEBUG], [test x"$enable_debug" = xyes])

dnl TODO: check if C++23 is supported

AC_CHECK_PROG([SLANGC], [slangc], [slangc])
AS_VAR_IF([SLANGC], [], [AC_MSG_ERROR([slangc not found])])
dnl TODO: check if slangc support Vulkan 1.4

PKG_CHECK_MODULES([GLFW3], [glfw3 >= 3.3.10])
PKG_CHECK_MODULES([VULKAN], [vulkan])
PKG_HAVE_DEFINE_WITH_MODULES([NCURSES], [ncurses >= 6.4.20230625])

AC_LANG_PUSH([C++])

m4_define([vulkan_required_api_variant], [[0]])
m4_define([vulkan_required_api], [[1.4.313]])
AC_MSG_CHECKING(
  [if Vulkan headers are variant ]vulkan_required_api_variant[ and version at least ]vulkan_required_api)
CXXFLAGS="$VULKAN_CFLAGS"
AC_COMPUTE_INT([vulkan_api_int], [VK_HEADER_VERSION_COMPLETE],
  [#include <vulkan/vulkan.h>],
  [AC_MSG_ERROR([cannot check Vulkan headers version])])
AS_VAR_ARITH([vulkan_api_variant], [$][vulkan_api_int \>\> 29])
AS_VAR_ARITH([vulkan_api_major], [\( ][$][vulkan_api_int \>\> 22 \) \& 127])
AS_VAR_ARITH([vulkan_api_minor], [\( ][$][vulkan_api_int \>\> 12 \) \& 1023])
AS_VAR_ARITH([vulkan_api_patch], [$][vulkan_api_int \& 4095])
vulkan_api="[$]vulkan_api_major.[$]vulkan_api_minor.[$]vulkan_api_patch"
AS_VAR_IF([vulkan_api_variant], vulkan_required_api_variant,, [
  AC_MSG_RESULT([no])
  AC_MSG_ERROR(
    [Vulkan headers are variant ][$][vulkan_api_variant, but variant ]vulkan_required_api_variant[ required])
])
AX_COMPARE_VERSION([$][vulkan_api], [ge], vulkan_required_api, [AC_MSG_RESULT([yes])], [
  AC_MSG_RESULT([no])
  AC_MSG_ERROR(
    [Vulkan headers are version ][$][vulkan_api, but version at least ]vulkan_required_api[ required])
])

AC_LANG_POP([C++])

CXXFLAGS="$CXXFLAGS_save"
LIBS="$LIBS_save"

AC_OUTPUT